1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
72
73
74
75
76
77
78
79
80
81
82
83
84
85
86
87
88
89
90
91
92
93
94
95
96
97
98
99
100
101
102
103
104
105
106
107
108
109
110
111
112
113
114
115
116
117
118
119
120
121
122
123
124
125
126
127
128
129
130
131
132
133
134
135
136
137
138
139
140
141
142
143
144
145
146
147
148
149
150
151
152
153
154
155
156
157
158
159
160
161
162
163
164
165
166
167
168
169
170
171
172
173
174
175
176
177
178
179
180
181
182
183
184
185
186
187
188
189
190
191
192
193
194
195
196
197
198
199
200
201
202
203
204
205
206
207
208
209
210
211
212
213
214
215
216
217
218
219
220
221
222
223
224
225
226
227
228
229
|
{* UltraStar Deluxe - Karaoke Game
*
* UltraStar Deluxe is the legal property of its developers, whose names
* are too numerous to list here. Please refer to the COPYRIGHT
* file distributed with this source distribution.
*
* This program is free software; you can redistribute it and/or
* modify it under the terms of the GNU General Public License
* as published by the Free Software Foundation; either version 2
* of the License, or (at your option) any later version.
*
* This program is distributed in the hope that it will be useful,
* but WITHOUT ANY WARRANTY; without even the implied warranty of
* MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE. See the
* GNU General Public License for more details.
*
* You should have received a copy of the GNU General Public License
* along with this program; see the file COPYING. If not, write to
* the Free Software Foundation, Inc., 51 Franklin Street, Fifth Floor,
* Boston, MA 02110-1301, USA.
*
* $URL$
* $Id$
*}
unit UUnicodeUtils;
interface
{$IFDEF FPC}
{$MODE Delphi}
{$ENDIF}
{$I switches.inc}
uses
SysUtils
{$IFDEF MSWINDOWS}
, Windows
{$ENDIF}
;
(*
* Character classes
*)
function IsAlphaChar(ch: WideChar): boolean;
function IsNumericChar(ch: WideChar): boolean;
function IsAlphaNumericChar(ch: WideChar): boolean;
function IsPunctuationChar(ch: WideChar): boolean;
function IsControlChar(ch: WideChar): boolean;
{*
* String format conversion
*}
function UTF8ToUCS4String(const str: UTF8String): UCS4String;
function UCS4ToUTF8String(const str: UCS4String): UTF8String; overload;
function UCS4ToUTF8String(ch: UCS4Char): UTF8String; overload;
{**
* Returns the number of characters (not bytes) in string str.
*}
function LengthUTF8(const str: UTF8String): integer;
{**
* Converts a UCS-4 char ch to its upper-case representation.
*}
function UCS4UpperCase(ch: UCS4Char): UCS4Char; overload;
{**
* Converts a UCS-4 string str to its upper-case representation.
*}
function UCS4UpperCase(const str: UCS4String): UCS4String; overload;
{**
*
*}
function UCS4CharToString(ch: UCS4Char): UCS4String;
(*
* Converts a WideString to its upper-case representation.
* Wrapper for WideUpperCase. Needed because some plattforms have problems with
* unicode support.
*
* Note that characters in UTF-16 might consist of one or two WideChar valus
* (see surrogates). So instead of using WideStringUpperCase(ch)[1] for single
* character access, convert to UCS-4 where each character is represented by
* one UCS4Char.
*)
function WideStringUpperCase(const str: WideString) : WideString; overload;
function WideStringUpperCase(ch: WideChar): WideString; overload;
implementation
function IsAlphaChar(ch: WideChar): boolean;
begin
{$IFDEF MSWINDOWS}
Result := IsCharAlphaW(ch);
{$ELSE}
// TODO: add chars > 255
case ch of
'A'..'Z', // A-Z
'a'..'z', // a-z
#170,#181,#186,
#192..#214,
#216..#246,
#248..#255:
Result := true;
else
Result := false;
end;
{$ENDIF}
end;
function IsNumericChar(ch: WideChar): boolean;
begin
// ignore non-arabic numerals as we do not want to handle them
case ch of
'0'..'9':
Result := true;
else
Result := false;
end;
end;
function IsAlphaNumericChar(ch: WideChar): boolean;
begin
Result := (IsAlphaChar(ch) or IsNumericChar(ch));
end;
function IsPunctuationChar(ch: WideChar): boolean;
begin
// TODO: add chars > 255?
case ch of
' '..'/',':'..'@','['..'`','{'..'~',
#160..#191,#215,#247:
Result := true;
else
Result := false;
end;
end;
function IsControlChar(ch: WideChar): boolean;
begin
case ch of
#0..#31,
#127..#159:
Result := true;
else
Result := false;
end;
end;
function UTF8ToUCS4String(const str: UTF8String): UCS4String;
begin
Result := WideStringToUCS4String(UTF8Decode(str));
end;
function UCS4ToUTF8String(const str: UCS4String): UTF8String;
begin
Result := UTF8Encode(UCS4StringToWideString(str));
end;
function UCS4ToUTF8String(ch: UCS4Char): UTF8String;
begin
Result := UCS4ToUTF8String(UCS4CharToString(ch));
end;
function LengthUTF8(const str: UTF8String): integer;
begin
Result := Length(UTF8ToUCS4String(str));
end;
function UCS4UpperCase(ch: UCS4Char): UCS4Char;
begin
Result := UCS4UpperCase(UCS4CharToString(ch))[0];
end;
function UCS4UpperCase(const str: UCS4String): UCS4String;
begin
// convert to upper-case as WideString and convert result back to UCS-4
Result := WideStringToUCS4String(
WideStringUpperCase(
UCS4StringToWideString(str)));
end;
function UCS4CharToString(ch: UCS4Char): UCS4String;
begin
SetLength(Result, 2);
Result[0] := ch;
Result[1] := 0;
end;
function WideStringUpperCase(ch: WideChar): WideString;
begin
// If WideChar #0 is converted to a WideString in Delphi, a string with
// length 1 and a single char #0 is returned. In FPC an empty (length=0)
// string will be returned. This will crash, if a non printable key was
// pressed, its char code (#0) is translated to upper-case and the the first
// character is accessed with Result[1].
// We cannot catch this error in the WideString parameter variant as the string
// has length 0 already.
// Force min. string length of 1
if (ch = #0) then
Result := #0
else
Result := WideStringUpperCase(WideString(ch));
end;
function WideStringUpperCase(const str: WideString): WideString;
begin
// On Linux and MacOSX the cwstring unit is necessary for Unicode function-calls.
// Otherwise you will get an EIntOverflow exception (thrown by unimplementedwidestring()).
// The Unicode manager cwstring does not work with MacOSX at the moment because
// of missing references to iconv.
{.$IFNDEF DARWIN}
{$IFDEF NOIGNORE}
Result := WideUpperCase(str)
{$ELSE}
Result := UTF8Decode(UpperCase(UTF8Encode(str)));
{$ENDIF}
end;
end.
|
