From 4c6d2f4cd49a4f6016026ef81db31c3656bb5e8c Mon Sep 17 00:00:00 2001
From: tobigun <tobigun@b956fd51-792f-4845-bead-9b4dfca2ff2c>
Date: Sat, 13 Sep 2008 08:27:50 +0000
Subject: Media modules moved from base to media

git-svn-id: svn://svn.code.sf.net/p/ultrastardx/svn/trunk@1374 b956fd51-792f-4845-bead-9b4dfca2ff2c
---
 src/media/UAudioInput_Portaudio.pas | 474 ++++++++++++++++++++++++++++++++++++
 1 file changed, 474 insertions(+)
 create mode 100644 src/media/UAudioInput_Portaudio.pas

(limited to 'src/media/UAudioInput_Portaudio.pas')

diff --git a/src/media/UAudioInput_Portaudio.pas b/src/media/UAudioInput_Portaudio.pas
new file mode 100644
index 00000000..9a1c3e99
--- /dev/null
+++ b/src/media/UAudioInput_Portaudio.pas
@@ -0,0 +1,474 @@
+unit UAudioInput_Portaudio;
+
+interface
+
+{$IFDEF FPC}
+  {$MODE Delphi}
+{$ENDIF}
+
+{$I ../switches.inc}
+
+
+uses
+  Classes,
+  SysUtils,
+  UMusic;
+
+implementation
+
+uses
+  {$IFDEF UsePortmixer}
+  portmixer,
+  {$ENDIF}
+  portaudio,
+  UAudioCore_Portaudio,
+  URecord,
+  UIni,
+  ULog,
+  UMain;
+
+type
+  TAudioInput_Portaudio = class(TAudioInputBase)
+    private
+      AudioCore: TAudioCore_Portaudio;
+      function EnumDevices(): boolean;
+    public
+      function GetName: String; override;
+      function InitializeRecord: boolean; override;
+      function FinalizeRecord: boolean; override;
+  end;
+
+  TPortaudioInputDevice = class(TAudioInputDevice)
+    private
+      RecordStream: PPaStream;
+      {$IFDEF UsePortmixer}
+      Mixer: PPxMixer;
+      {$ENDIF}
+      PaDeviceIndex:  TPaDeviceIndex;
+    public
+      function Open(): boolean;
+      function Close(): boolean;
+      function Start(): boolean; override;
+      function Stop(): boolean;  override;
+
+      function GetVolume(): single;        override;
+      procedure SetVolume(Volume: single); override;
+  end;
+
+function MicrophoneCallback(input: Pointer; output: Pointer; frameCount: Longword;
+      timeInfo: PPaStreamCallbackTimeInfo; statusFlags: TPaStreamCallbackFlags;
+      inputDevice: Pointer): Integer; cdecl; forward;
+
+function MicrophoneTestCallback(input: Pointer; output: Pointer; frameCount: Longword;
+      timeInfo: PPaStreamCallbackTimeInfo; statusFlags: TPaStreamCallbackFlags;
+      inputDevice: Pointer): Integer; cdecl; forward;
+
+
+{ TPortaudioInputDevice }
+
+function TPortaudioInputDevice.Open(): boolean;
+var
+  Error:       TPaError;
+  inputParams: TPaStreamParameters;
+  deviceInfo:  PPaDeviceInfo;
+  SourceIndex: integer;
+begin
+  Result := false;
+
+  // get input latency info
+  deviceInfo := Pa_GetDeviceInfo(PaDeviceIndex);
+
+  // set input stream parameters
+  with inputParams do
+  begin
+    device := PaDeviceIndex;
+    channelCount := AudioFormat.Channels;
+    sampleFormat := paInt16;
+    suggestedLatency := deviceInfo^.defaultLowInputLatency;
+    hostApiSpecificStreamInfo := nil;
+  end;
+
+  //Log.LogStatus(deviceInfo^.name, 'Portaudio');
+  //Log.LogStatus(floattostr(deviceInfo^.defaultLowInputLatency), 'Portaudio');
+
+  // open input stream
+  Error := Pa_OpenStream(RecordStream, @inputParams, nil,
+      AudioFormat.SampleRate,
+      paFramesPerBufferUnspecified, paNoFlag,
+      @MicrophoneCallback, Pointer(Self));
+  if(Error <> paNoError) then
+  begin
+    Log.LogError('Error opening stream: ' + Pa_GetErrorText(Error), 'TPortaudioInputDevice.Open');
+    Exit;
+  end;
+
+  {$IFDEF UsePortmixer}
+    // open default mixer
+    Mixer := Px_OpenMixer(RecordStream, 0);
+    if (Mixer = nil) then
+    begin
+      Log.LogError('Error opening mixer: ' + Pa_GetErrorText(Error), 'TPortaudioInputDevice.Open');
+    end
+    else
+    begin
+      // save current source selection and select new source
+      SourceIndex := Ini.InputDeviceConfig[CfgIndex].Input-1;
+      if (SourceIndex = -1) then
+      begin
+        // nothing to do if default source is used
+        SourceRestore := -1;
+      end
+      else
+      begin
+        // store current source-index and select new source
+        SourceRestore := Px_GetCurrentInputSource(Mixer); // -1 in error case
+        Px_SetCurrentInputSource(Mixer, SourceIndex);
+      end;
+    end;
+  {$ENDIF}
+
+  Result := true;
+end;
+
+function TPortaudioInputDevice.Start(): boolean;
+var
+  Error:       TPaError;
+begin
+  Result := false;
+
+  // recording already started -> stop first
+  if (RecordStream <> nil) then
+    Stop();
+
+  // TODO: Do not open the device here (takes too much time).
+  if (not Open()) then
+    Exit;
+
+  // start capture
+  Error := Pa_StartStream(RecordStream);
+  if(Error <> paNoError) then
+  begin
+    Log.LogError('Error starting stream: ' + Pa_GetErrorText(Error), 'TPortaudioInputDevice.Start');
+    Close();
+    RecordStream := nil;
+    Exit;
+  end;
+
+  Result := true;
+end;
+
+function TPortaudioInputDevice.Stop(): boolean;
+var
+  Error: TPaError;
+begin
+  Result := false;
+
+  if (RecordStream = nil) then
+    Exit;
+
+  // Note: do NOT call Pa_StopStream here!
+  // It gets stuck on devices with non-working callback as Pa_StopStream
+  // waits until all buffers have been handled (which never occurs in that case).
+  Error := Pa_AbortStream(RecordStream);
+  if (Error <> paNoError) then
+  begin
+    Log.LogError('Pa_AbortStream: ' + Pa_GetErrorText(Error), 'TPortaudioInputDevice.Stop');
+  end;
+
+  Result := Close();
+end;
+
+function TPortaudioInputDevice.Close(): boolean;
+var
+  Error: TPaError;
+begin
+  {$IFDEF UsePortmixer}
+    if (Mixer <> nil) then
+    begin
+      // restore source selection
+      if (SourceRestore >= 0) then
+      begin
+        Px_SetCurrentInputSource(Mixer, SourceRestore);
+      end;
+
+      // close mixer
+      Px_CloseMixer(Mixer);
+      Mixer := nil;
+    end;
+  {$ENDIF}
+
+  Error := Pa_CloseStream(RecordStream);
+  if (Error <> paNoError) then
+  begin
+    Log.LogError('Pa_CloseStream: ' + Pa_GetErrorText(Error), 'TPortaudioInputDevice.Close');
+    Result := false;
+  end
+  else
+  begin
+    Result := true;
+  end;
+
+  RecordStream := nil;
+end;
+
+function TPortaudioInputDevice.GetVolume(): single;
+begin
+  Result := 0;
+  {$IFDEF UsePortmixer}
+    if (Mixer <> nil) then
+      Result := Px_GetInputVolume(Mixer);
+  {$ENDIF}
+end;
+
+procedure TPortaudioInputDevice.SetVolume(Volume: single);
+begin
+  {$IFDEF UsePortmixer}
+    if (Mixer <> nil) then
+    begin
+      // clip to valid range
+      if (Volume > 1.0) then
+        Volume := 1.0
+      else if (Volume < 0) then
+        Volume := 0;
+      Px_SetInputVolume(Mixer, Volume);
+    end;
+  {$ENDIF}
+end;
+
+
+{ TAudioInput_Portaudio }
+
+function TAudioInput_Portaudio.GetName: String;
+begin
+  result := 'Portaudio';
+end;
+
+function TAudioInput_Portaudio.EnumDevices(): boolean;
+var
+  i:           integer;
+  paApiIndex:  TPaHostApiIndex;
+  paApiInfo:   PPaHostApiInfo;
+  deviceName:  string;
+  deviceIndex: TPaDeviceIndex;
+  deviceInfo:  PPaDeviceInfo;
+  channelCnt:  integer;
+  SC:          integer; // soundcard
+  err:         TPaError;
+  errMsg:      string;
+  paDevice:    TPortaudioInputDevice;
+  inputParams: TPaStreamParameters;
+  stream:      PPaStream;
+  streamInfo:  PPaStreamInfo;
+  sampleRate:  double;
+  latency:     TPaTime;
+  {$IFDEF UsePortmixer}
+  mixer:       PPxMixer;
+  sourceCnt:   integer;
+  sourceIndex: integer;
+  sourceName:  string;
+  {$ENDIF}
+  cbPolls: integer;
+  cbWorks: boolean;
+begin
+  Result := false;
+
+  // choose the best available Audio-API
+  paApiIndex := AudioCore.GetPreferredApiIndex();
+  if(paApiIndex = -1) then
+  begin
+    Log.LogError('No working Audio-API found', 'TAudioInput_Portaudio.EnumDevices');
+    Exit;
+  end;
+
+  paApiInfo := Pa_GetHostApiInfo(paApiIndex);
+
+  SC := 0;
+
+  // init array-size to max. input-devices count
+  SetLength(AudioInputProcessor.DeviceList, paApiInfo^.deviceCount);
+  for i:= 0 to High(AudioInputProcessor.DeviceList) do
+  begin
+    // convert API-specific device-index to global index
+    deviceIndex := Pa_HostApiDeviceIndexToDeviceIndex(paApiIndex, i);
+    deviceInfo := Pa_GetDeviceInfo(deviceIndex);
+
+    channelCnt := deviceInfo^.maxInputChannels;
+
+    // current device is no input device -> skip
+    if (channelCnt <= 0) then
+      continue;
+
+    // portaudio returns a channel-count of 128 for some devices
+    // (e.g. the "default"-device), so we have to detect those
+    // fantasy channel counts.
+    if (channelCnt > 8) then
+      channelCnt := 2;
+
+    paDevice := TPortaudioInputDevice.Create();
+    AudioInputProcessor.DeviceList[SC] := paDevice;
+
+    // retrieve device-name
+    deviceName := deviceInfo^.name;
+    paDevice.Name := deviceName;
+    paDevice.PaDeviceIndex := deviceIndex;
+
+    sampleRate := deviceInfo^.defaultSampleRate;
+
+    // on vista and xp the defaultLowInputLatency may be set to 0 but it works.
+    // TODO: correct too low latencies (what is a too low latency, maybe < 10ms?)
+    latency := deviceInfo^.defaultLowInputLatency;
+
+    // setup desired input parameters
+    // TODO: retry with input-latency set to 20ms (defaultLowInputLatency might
+    //       not be set correctly in OSS)
+    with inputParams do
+    begin
+      device := deviceIndex;
+      channelCount := channelCnt;
+      sampleFormat := paInt16;
+      suggestedLatency := latency;
+      hostApiSpecificStreamInfo := nil;
+    end;
+
+    // check souncard and adjust sample-rate
+    if (not AudioCore.TestDevice(@inputParams, nil, sampleRate)) then
+    begin
+      // ignore device if it does not work
+      Log.LogError('Device "'+paDevice.Name+'" does not work',
+                   'TAudioInput_Portaudio.EnumDevices');
+      paDevice.Free();
+      continue;
+    end;
+
+    // open device for further info
+    err := Pa_OpenStream(stream, @inputParams, nil, sampleRate,
+        paFramesPerBufferUnspecified, paNoFlag, @MicrophoneTestCallback, nil);
+    if(err <> paNoError) then
+    begin
+      // unable to open device -> skip
+      errMsg := Pa_GetErrorText(err);
+      Log.LogError('Device error: "'+ deviceName +'" ('+ errMsg +')',
+                   'TAudioInput_Portaudio.EnumDevices');
+      paDevice.Free();
+      continue;
+    end;
+
+    // adjust sample-rate (might be changed by portaudio)
+    streamInfo := Pa_GetStreamInfo(stream);
+    if (streamInfo <> nil) then
+    begin
+      if (sampleRate <> streamInfo^.sampleRate) then
+      begin
+        Log.LogStatus('Portaudio changed Samplerate from ' + FloatToStr(sampleRate) +
+            ' to ' + FloatToStr(streamInfo^.sampleRate),
+            'TAudioInput_Portaudio.InitializeRecord');
+        sampleRate := streamInfo^.sampleRate;
+      end;
+    end;
+    
+    // create audio-format info and resize capture-buffer array
+    paDevice.AudioFormat := TAudioFormatInfo.Create(
+        channelCnt,
+        sampleRate,
+        asfS16
+    );
+    SetLength(paDevice.CaptureChannel, paDevice.AudioFormat.Channels);
+
+    Log.LogStatus('InputDevice "'+paDevice.Name+'"@' +
+        IntToStr(paDevice.AudioFormat.Channels)+'x'+
+        FloatToStr(paDevice.AudioFormat.SampleRate)+'Hz ('+
+        FloatTostr(inputParams.suggestedLatency)+'sec)' ,
+        'Portaudio.EnumDevices');
+
+    // portaudio does not provide a source-type check
+    paDevice.MicSource := -1;
+    paDevice.SourceRestore := -1;
+
+    // add a virtual default source (will not change mixer-settings)
+    SetLength(paDevice.Source, 1);
+    paDevice.Source[0].Name := DEFAULT_SOURCE_NAME;
+
+    {$IFDEF UsePortmixer}
+      // use default mixer
+      mixer := Px_OpenMixer(stream, 0);
+
+      // get input count
+      sourceCnt := Px_GetNumInputSources(mixer);
+      SetLength(paDevice.Source, sourceCnt+1);
+
+      // get input names
+      for sourceIndex := 1 to sourceCnt do
+      begin
+        sourceName := Px_GetInputSourceName(mixer, sourceIndex-1);
+        paDevice.Source[sourceIndex].Name := sourceName;
+      end;
+
+      Px_CloseMixer(mixer);
+    {$ENDIF}
+
+    // close test-stream
+    Pa_CloseStream(stream);
+
+    Inc(SC);
+  end;
+
+  // adjust size to actual input-device count
+  SetLength(AudioInputProcessor.DeviceList, SC);
+
+  Log.LogStatus('#Input-Devices: ' + inttostr(SC), 'Portaudio');
+
+  Result := true;
+end;
+
+function TAudioInput_Portaudio.InitializeRecord(): boolean;
+var
+  err: TPaError;
+begin
+  AudioCore := TAudioCore_Portaudio.GetInstance();
+
+  // initialize portaudio
+  err := Pa_Initialize();
+  if(err <> paNoError) then
+  begin
+    Log.LogError(Pa_GetErrorText(err), 'TAudioInput_Portaudio.InitializeRecord');
+    Result := false;
+    Exit;
+  end;
+
+  Result := EnumDevices();
+end;
+
+function TAudioInput_Portaudio.FinalizeRecord: boolean;
+begin
+  CaptureStop;
+  Pa_Terminate();
+  Result := inherited FinalizeRecord();
+end;
+
+{*
+ * Portaudio input capture callback.
+ *}
+function MicrophoneCallback(input: Pointer; output: Pointer; frameCount: Longword;
+      timeInfo: PPaStreamCallbackTimeInfo; statusFlags: TPaStreamCallbackFlags;
+      inputDevice: Pointer): Integer; cdecl;
+begin
+  AudioInputProcessor.HandleMicrophoneData(input, frameCount*4, inputDevice);
+  result := paContinue;
+end;
+
+{*
+ * Portaudio test capture callback.
+ *}
+function MicrophoneTestCallback(input: Pointer; output: Pointer; frameCount: Longword;
+      timeInfo: PPaStreamCallbackTimeInfo; statusFlags: TPaStreamCallbackFlags;
+      inputDevice: Pointer): Integer; cdecl;
+begin
+  // this callback is called only once
+  result := paAbort;
+end;
+
+
+initialization
+  MediaManager.add(TAudioInput_Portaudio.Create);
+
+end.
-- 
cgit v1.2.3


From f16756422a5dbb24ce1b751bb9e2bb1de4f19713 Mon Sep 17 00:00:00 2001
From: tobigun <tobigun@b956fd51-792f-4845-bead-9b4dfca2ff2c>
Date: Tue, 23 Sep 2008 21:17:50 +0000
Subject: added file headers

git-svn-id: svn://svn.code.sf.net/p/ultrastardx/svn/trunk@1404 b956fd51-792f-4845-bead-9b4dfca2ff2c
---
 src/media/UAudioInput_Portaudio.pas | 25 +++++++++++++++++++++++++
 1 file changed, 25 insertions(+)

(limited to 'src/media/UAudioInput_Portaudio.pas')

diff --git a/src/media/UAudioInput_Portaudio.pas b/src/media/UAudioInput_Portaudio.pas
index 9a1c3e99..14291658 100644
--- a/src/media/UAudioInput_Portaudio.pas
+++ b/src/media/UAudioInput_Portaudio.pas
@@ -1,3 +1,28 @@
+{* UltraStar Deluxe - Karaoke Game
+ *
+ * UltraStar Deluxe is the legal property of its developers, whose names
+ * are too numerous to list here. Please refer to the COPYRIGHT
+ * file distributed with this source distribution.
+ *
+ * This program is free software; you can redistribute it and/or
+ * modify it under the terms of the GNU General Public License
+ * as published by the Free Software Foundation; either version 2
+ * of the License, or (at your option) any later version.
+ *
+ * This program is distributed in the hope that it will be useful,
+ * but WITHOUT ANY WARRANTY; without even the implied warranty of
+ * MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
+ * GNU General Public License for more details.
+ *
+ * You should have received a copy of the GNU General Public License
+ * along with this program; see the file COPYING. If not, write to
+ * the Free Software Foundation, Inc., 51 Franklin Street, Fifth Floor,
+ * Boston, MA 02110-1301, USA.
+ *
+ * $URL$
+ * $Id$
+ *}
+
 unit UAudioInput_Portaudio;
 
 interface
-- 
cgit v1.2.3


From d397c0364763dbf0449adb2c8568377bba62d7fa Mon Sep 17 00:00:00 2001
From: k-m_schindler <k-m_schindler@b956fd51-792f-4845-bead-9b4dfca2ff2c>
Date: Sat, 27 Sep 2008 23:28:57 +0000
Subject: remove some white space. no code change

git-svn-id: svn://svn.code.sf.net/p/ultrastardx/svn/trunk@1416 b956fd51-792f-4845-bead-9b4dfca2ff2c
---
 src/media/UAudioInput_Portaudio.pas | 1 -
 1 file changed, 1 deletion(-)

(limited to 'src/media/UAudioInput_Portaudio.pas')

diff --git a/src/media/UAudioInput_Portaudio.pas b/src/media/UAudioInput_Portaudio.pas
index 14291658..53080a03 100644
--- a/src/media/UAudioInput_Portaudio.pas
+++ b/src/media/UAudioInput_Portaudio.pas
@@ -33,7 +33,6 @@ interface
 
 {$I ../switches.inc}
 
-
 uses
   Classes,
   SysUtils,
-- 
cgit v1.2.3


From 9ec474eb703bfb72a88b26f63d40039c860919e6 Mon Sep 17 00:00:00 2001
From: k-m_schindler <k-m_schindler@b956fd51-792f-4845-bead-9b4dfca2ff2c>
Date: Thu, 9 Apr 2009 22:48:04 +0000
Subject: Warnings and Notes cleanup

git-svn-id: svn://svn.code.sf.net/p/ultrastardx/svn/trunk@1662 b956fd51-792f-4845-bead-9b4dfca2ff2c
---
 src/media/UAudioInput_Portaudio.pas | 3 ---
 1 file changed, 3 deletions(-)

(limited to 'src/media/UAudioInput_Portaudio.pas')

diff --git a/src/media/UAudioInput_Portaudio.pas b/src/media/UAudioInput_Portaudio.pas
index 53080a03..31d2882b 100644
--- a/src/media/UAudioInput_Portaudio.pas
+++ b/src/media/UAudioInput_Portaudio.pas
@@ -95,7 +95,6 @@ var
   Error:       TPaError;
   inputParams: TPaStreamParameters;
   deviceInfo:  PPaDeviceInfo;
-  SourceIndex: integer;
 begin
   Result := false;
 
@@ -291,8 +290,6 @@ var
   sourceIndex: integer;
   sourceName:  string;
   {$ENDIF}
-  cbPolls: integer;
-  cbWorks: boolean;
 begin
   Result := false;
 
-- 
cgit v1.2.3


From 5ae777e92dd891a0aa8010caf584e708cd508b88 Mon Sep 17 00:00:00 2001
From: k-m_schindler <k-m_schindler@b956fd51-792f-4845-bead-9b4dfca2ff2c>
Date: Wed, 24 Feb 2010 19:38:05 +0000
Subject: unifiy the name of portaudio inputs

git-svn-id: svn://svn.code.sf.net/p/ultrastardx/svn/trunk@2153 b956fd51-792f-4845-bead-9b4dfca2ff2c
---
 src/media/UAudioInput_Portaudio.pas | 2 +-
 1 file changed, 1 insertion(+), 1 deletion(-)

(limited to 'src/media/UAudioInput_Portaudio.pas')

diff --git a/src/media/UAudioInput_Portaudio.pas b/src/media/UAudioInput_Portaudio.pas
index 31d2882b..e278e69a 100644
--- a/src/media/UAudioInput_Portaudio.pas
+++ b/src/media/UAudioInput_Portaudio.pas
@@ -330,7 +330,7 @@ begin
 
     // retrieve device-name
     deviceName := deviceInfo^.name;
-    paDevice.Name := deviceName;
+    paDevice.Name := UnifyDeviceName(deviceName, deviceIndex);
     paDevice.PaDeviceIndex := deviceIndex;
 
     sampleRate := deviceInfo^.defaultSampleRate;
-- 
cgit v1.2.3


From f948cdceadcd8e6161fbd2c6effecdd079361510 Mon Sep 17 00:00:00 2001
From: k-m_schindler <k-m_schindler@b956fd51-792f-4845-bead-9b4dfca2ff2c>
Date: Thu, 25 Feb 2010 11:10:26 +0000
Subject: cosmetics. no code change.

git-svn-id: svn://svn.code.sf.net/p/ultrastardx/svn/trunk@2155 b956fd51-792f-4845-bead-9b4dfca2ff2c
---
 src/media/UAudioInput_Portaudio.pas | 41 ++++++++++++++++++-------------------
 1 file changed, 20 insertions(+), 21 deletions(-)

(limited to 'src/media/UAudioInput_Portaudio.pas')

diff --git a/src/media/UAudioInput_Portaudio.pas b/src/media/UAudioInput_Portaudio.pas
index e278e69a..4a021cc7 100644
--- a/src/media/UAudioInput_Portaudio.pas
+++ b/src/media/UAudioInput_Portaudio.pas
@@ -46,10 +46,10 @@ uses
   {$ENDIF}
   portaudio,
   UAudioCore_Portaudio,
-  URecord,
   UIni,
   ULog,
-  UMain;
+  UMain,
+  URecord;
 
 type
   TAudioInput_Portaudio = class(TAudioInputBase)
@@ -57,7 +57,7 @@ type
       AudioCore: TAudioCore_Portaudio;
       function EnumDevices(): boolean;
     public
-      function GetName: String; override;
+      function GetName: string; override;
       function InitializeRecord: boolean; override;
       function FinalizeRecord: boolean; override;
   end;
@@ -70,22 +70,22 @@ type
       {$ENDIF}
       PaDeviceIndex:  TPaDeviceIndex;
     public
-      function Open(): boolean;
+      function Open():  boolean;
       function Close(): boolean;
       function Start(): boolean; override;
-      function Stop(): boolean;  override;
+      function Stop():  boolean; override;
 
       function GetVolume(): single;        override;
       procedure SetVolume(Volume: single); override;
   end;
 
-function MicrophoneCallback(input: Pointer; output: Pointer; frameCount: Longword;
+function MicrophoneCallback(input: pointer; output: pointer; frameCount: longword;
       timeInfo: PPaStreamCallbackTimeInfo; statusFlags: TPaStreamCallbackFlags;
-      inputDevice: Pointer): Integer; cdecl; forward;
+      inputDevice: pointer): integer; cdecl; forward;
 
-function MicrophoneTestCallback(input: Pointer; output: Pointer; frameCount: Longword;
+function MicrophoneTestCallback(input: pointer; output: pointer; frameCount: longword;
       timeInfo: PPaStreamCallbackTimeInfo; statusFlags: TPaStreamCallbackFlags;
-      inputDevice: Pointer): Integer; cdecl; forward;
+      inputDevice: pointer): integer; cdecl; forward;
 
 
 { TPortaudioInputDevice }
@@ -118,8 +118,8 @@ begin
   Error := Pa_OpenStream(RecordStream, @inputParams, nil,
       AudioFormat.SampleRate,
       paFramesPerBufferUnspecified, paNoFlag,
-      @MicrophoneCallback, Pointer(Self));
-  if(Error <> paNoError) then
+      @MicrophoneCallback, pointer(Self));
+  if (Error <> paNoError) then
   begin
     Log.LogError('Error opening stream: ' + Pa_GetErrorText(Error), 'TPortaudioInputDevice.Open');
     Exit;
@@ -155,7 +155,7 @@ end;
 
 function TPortaudioInputDevice.Start(): boolean;
 var
-  Error:       TPaError;
+  Error: TPaError;
 begin
   Result := false;
 
@@ -169,7 +169,7 @@ begin
 
   // start capture
   Error := Pa_StartStream(RecordStream);
-  if(Error <> paNoError) then
+  if (Error <> paNoError) then
   begin
     Log.LogError('Error starting stream: ' + Pa_GetErrorText(Error), 'TPortaudioInputDevice.Start');
     Close();
@@ -295,7 +295,7 @@ begin
 
   // choose the best available Audio-API
   paApiIndex := AudioCore.GetPreferredApiIndex();
-  if(paApiIndex = -1) then
+  if (paApiIndex = -1) then
   begin
     Log.LogError('No working Audio-API found', 'TAudioInput_Portaudio.EnumDevices');
     Exit;
@@ -364,7 +364,7 @@ begin
     // open device for further info
     err := Pa_OpenStream(stream, @inputParams, nil, sampleRate,
         paFramesPerBufferUnspecified, paNoFlag, @MicrophoneTestCallback, nil);
-    if(err <> paNoError) then
+    if (err <> paNoError) then
     begin
       // unable to open device -> skip
       errMsg := Pa_GetErrorText(err);
@@ -449,7 +449,7 @@ begin
 
   // initialize portaudio
   err := Pa_Initialize();
-  if(err <> paNoError) then
+  if (err <> paNoError) then
   begin
     Log.LogError(Pa_GetErrorText(err), 'TAudioInput_Portaudio.InitializeRecord');
     Result := false;
@@ -469,9 +469,9 @@ end;
 {*
  * Portaudio input capture callback.
  *}
-function MicrophoneCallback(input: Pointer; output: Pointer; frameCount: Longword;
+function MicrophoneCallback(input: pointer; output: pointer; frameCount: longword;
       timeInfo: PPaStreamCallbackTimeInfo; statusFlags: TPaStreamCallbackFlags;
-      inputDevice: Pointer): Integer; cdecl;
+      inputDevice: pointer): integer; cdecl;
 begin
   AudioInputProcessor.HandleMicrophoneData(input, frameCount*4, inputDevice);
   result := paContinue;
@@ -480,15 +480,14 @@ end;
 {*
  * Portaudio test capture callback.
  *}
-function MicrophoneTestCallback(input: Pointer; output: Pointer; frameCount: Longword;
+function MicrophoneTestCallback(input: pointer; output: pointer; frameCount: longword;
       timeInfo: PPaStreamCallbackTimeInfo; statusFlags: TPaStreamCallbackFlags;
-      inputDevice: Pointer): Integer; cdecl;
+      inputDevice: pointer): integer; cdecl;
 begin
   // this callback is called only once
   result := paAbort;
 end;
 
-
 initialization
   MediaManager.add(TAudioInput_Portaudio.Create);
 
-- 
cgit v1.2.3


From 03d4c6996af2582d672454b0f5a1a6e4b9cbe5ad Mon Sep 17 00:00:00 2001
From: k-m_schindler <k-m_schindler@b956fd51-792f-4845-bead-9b4dfca2ff2c>
Date: Fri, 12 Mar 2010 21:11:54 +0000
Subject: rename cosmetics. no code change.

git-svn-id: svn://svn.code.sf.net/p/ultrastardx/svn/trunk@2192 b956fd51-792f-4845-bead-9b4dfca2ff2c
---
 src/media/UAudioInput_Portaudio.pas | 50 ++++++++++++++++++-------------------
 1 file changed, 25 insertions(+), 25 deletions(-)

(limited to 'src/media/UAudioInput_Portaudio.pas')

diff --git a/src/media/UAudioInput_Portaudio.pas b/src/media/UAudioInput_Portaudio.pas
index 4a021cc7..c5ec8115 100644
--- a/src/media/UAudioInput_Portaudio.pas
+++ b/src/media/UAudioInput_Portaudio.pas
@@ -268,27 +268,27 @@ end;
 
 function TAudioInput_Portaudio.EnumDevices(): boolean;
 var
-  i:           integer;
-  paApiIndex:  TPaHostApiIndex;
-  paApiInfo:   PPaHostApiInfo;
-  deviceName:  string;
-  deviceIndex: TPaDeviceIndex;
-  deviceInfo:  PPaDeviceInfo;
-  channelCnt:  integer;
-  SC:          integer; // soundcard
-  err:         TPaError;
-  errMsg:      string;
-  paDevice:    TPortaudioInputDevice;
-  inputParams: TPaStreamParameters;
-  stream:      PPaStream;
-  streamInfo:  PPaStreamInfo;
-  sampleRate:  double;
-  latency:     TPaTime;
+  i:            integer;
+  paApiIndex:   TPaHostApiIndex;
+  paApiInfo:    PPaHostApiInfo;
+  deviceName:   string;
+  deviceIndex:  TPaDeviceIndex;
+  deviceInfo:   PPaDeviceInfo;
+  channelCnt:   integer;
+  soundcardCnt: integer;
+  err:          TPaError;
+  errMsg:       string;
+  paDevice:     TPortaudioInputDevice;
+  inputParams:  TPaStreamParameters;
+  stream:       PPaStream;
+  streamInfo:   PPaStreamInfo;
+  sampleRate:   double;
+  latency:      TPaTime;
   {$IFDEF UsePortmixer}
-  mixer:       PPxMixer;
-  sourceCnt:   integer;
-  sourceIndex: integer;
-  sourceName:  string;
+  mixer:        PPxMixer;
+  sourceCnt:    integer;
+  sourceIndex:  integer;
+  sourceName:   string;
   {$ENDIF}
 begin
   Result := false;
@@ -303,7 +303,7 @@ begin
 
   paApiInfo := Pa_GetHostApiInfo(paApiIndex);
 
-  SC := 0;
+  soundcardCnt := 0;
 
   // init array-size to max. input-devices count
   SetLength(AudioInputProcessor.DeviceList, paApiInfo^.deviceCount);
@@ -326,7 +326,7 @@ begin
       channelCnt := 2;
 
     paDevice := TPortaudioInputDevice.Create();
-    AudioInputProcessor.DeviceList[SC] := paDevice;
+    AudioInputProcessor.DeviceList[soundCardCnt] := paDevice;
 
     // retrieve device-name
     deviceName := deviceInfo^.name;
@@ -430,13 +430,13 @@ begin
     // close test-stream
     Pa_CloseStream(stream);
 
-    Inc(SC);
+    Inc(soundCardCnt);
   end;
 
   // adjust size to actual input-device count
-  SetLength(AudioInputProcessor.DeviceList, SC);
+  SetLength(AudioInputProcessor.DeviceList, soundCardCnt);
 
-  Log.LogStatus('#Input-Devices: ' + inttostr(SC), 'Portaudio');
+  Log.LogStatus('#Input-Devices: ' + inttostr(soundCardCnt), 'Portaudio');
 
   Result := true;
 end;
-- 
cgit v1.2.3


From f1566a45ac7de81f31a1b419d88e1742089ae56d Mon Sep 17 00:00:00 2001
From: whiteshark0 <whiteshark0@b956fd51-792f-4845-bead-9b4dfca2ff2c>
Date: Tue, 13 Apr 2010 16:23:14 +0000
Subject: =?UTF-8?q?-=20save=20input=20device=20names=20as=20UTF8Strings=20?=
 =?UTF-8?q?-=20device=20names=20of=20basslib=20are=20assumed=20to=20be=20i?=
 =?UTF-8?q?n=20local=20encoding=20-=20device=20names=20of=20portaudio=20ar?=
 =?UTF-8?q?e=20assumed=20to=20be=20in=20utf-8=20fixes:=20display=20of=20de?=
 =?UTF-8?q?vice=20names=20w/=20special=20characters=20w/=20basslib=20('?=
 =?UTF-8?q?=C3=A4'=20for=20me)=20to-do:=20proof=20encoding=20of=20device?=
 =?UTF-8?q?=20names=20for=20basslib=20and=20portaudio?=
MIME-Version: 1.0
Content-Type: text/plain; charset=UTF-8
Content-Transfer-Encoding: 8bit

git-svn-id: svn://svn.code.sf.net/p/ultrastardx/svn/trunk@2234 b956fd51-792f-4845-bead-9b4dfca2ff2c
---
 src/media/UAudioInput_Portaudio.pas | 2 +-
 1 file changed, 1 insertion(+), 1 deletion(-)

(limited to 'src/media/UAudioInput_Portaudio.pas')

diff --git a/src/media/UAudioInput_Portaudio.pas b/src/media/UAudioInput_Portaudio.pas
index c5ec8115..95b0f104 100644
--- a/src/media/UAudioInput_Portaudio.pas
+++ b/src/media/UAudioInput_Portaudio.pas
@@ -271,7 +271,7 @@ var
   i:            integer;
   paApiIndex:   TPaHostApiIndex;
   paApiInfo:    PPaHostApiInfo;
-  deviceName:   string;
+  deviceName:   UTF8String;
   deviceIndex:  TPaDeviceIndex;
   deviceInfo:   PPaDeviceInfo;
   channelCnt:   integer;
-- 
cgit v1.2.3


From ec49bde7e1919e5a460c05903b6ccafc00be0455 Mon Sep 17 00:00:00 2001
From: tobigun <tobigun@b956fd51-792f-4845-bead-9b4dfca2ff2c>
Date: Mon, 19 Apr 2010 21:40:23 +0000
Subject: bugfix for crash with portaudio (all platforms): -
 UAudioInput_Portaudio: UnifyDeviceNames was called with the wrong index

further changes:
- BASS input source-names seem to be encoded with local encoding and are converted to UTF8
- Portaudio source and device names encoding is auto-detected and converted to UTF8
- some clean-up

git-svn-id: svn://svn.code.sf.net/p/ultrastardx/svn/trunk@2252 b956fd51-792f-4845-bead-9b4dfca2ff2c
---
 src/media/UAudioInput_Portaudio.pas | 57 ++++++++++++++++++++++++-------------
 1 file changed, 38 insertions(+), 19 deletions(-)

(limited to 'src/media/UAudioInput_Portaudio.pas')

diff --git a/src/media/UAudioInput_Portaudio.pas b/src/media/UAudioInput_Portaudio.pas
index 95b0f104..26919d42 100644
--- a/src/media/UAudioInput_Portaudio.pas
+++ b/src/media/UAudioInput_Portaudio.pas
@@ -46,6 +46,8 @@ uses
   {$ENDIF}
   portaudio,
   UAudioCore_Portaudio,
+  UUnicodeUtils,
+  UTextEncoding,
   UIni,
   ULog,
   UMain,
@@ -88,6 +90,20 @@ function MicrophoneTestCallback(input: pointer; output: pointer; frameCount: lon
       inputDevice: pointer): integer; cdecl; forward;
 
 
+{**
+ * Converts a string returned by Portaudio into UTF8.
+ * If the string already is in UTF8 no conversion is performed, otherwise
+ * the local encoding is used. 
+ *}
+function ConvertPaStringToUTF8(const Str: RawByteString): UTF8String;
+begin
+  if (IsUTF8String(Str)) then
+    Result := Str
+  else
+    Result := DecodeStringUTF8(Str, encLocale);  
+end;
+
+
 { TPortaudioInputDevice }
 
 function TPortaudioInputDevice.Open(): boolean;
@@ -95,6 +111,9 @@ var
   Error:       TPaError;
   inputParams: TPaStreamParameters;
   deviceInfo:  PPaDeviceInfo;
+  {$IFDEF UsePortmixer}
+  SourceIndex: integer;
+  {$ENDIF}
 begin
   Result := false;
 
@@ -269,13 +288,13 @@ end;
 function TAudioInput_Portaudio.EnumDevices(): boolean;
 var
   i:            integer;
+  deviceName:   UTF8String;
   paApiIndex:   TPaHostApiIndex;
   paApiInfo:    PPaHostApiInfo;
-  deviceName:   UTF8String;
-  deviceIndex:  TPaDeviceIndex;
-  deviceInfo:   PPaDeviceInfo;
+  paDeviceIndex:TPaDeviceIndex;
+  paDeviceInfo: PPaDeviceInfo;
   channelCnt:   integer;
-  soundcardCnt: integer;
+  deviceIndex:  integer;
   err:          TPaError;
   errMsg:       string;
   paDevice:     TPortaudioInputDevice;
@@ -288,7 +307,7 @@ var
   mixer:        PPxMixer;
   sourceCnt:    integer;
   sourceIndex:  integer;
-  sourceName:   string;
+  sourceName:   UTF8String;
   {$ENDIF}
 begin
   Result := false;
@@ -303,17 +322,17 @@ begin
 
   paApiInfo := Pa_GetHostApiInfo(paApiIndex);
 
-  soundcardCnt := 0;
+  deviceIndex := 0;
 
   // init array-size to max. input-devices count
   SetLength(AudioInputProcessor.DeviceList, paApiInfo^.deviceCount);
   for i:= 0 to High(AudioInputProcessor.DeviceList) do
   begin
     // convert API-specific device-index to global index
-    deviceIndex := Pa_HostApiDeviceIndexToDeviceIndex(paApiIndex, i);
-    deviceInfo := Pa_GetDeviceInfo(deviceIndex);
+    paDeviceIndex := Pa_HostApiDeviceIndexToDeviceIndex(paApiIndex, i);
+    paDeviceInfo := Pa_GetDeviceInfo(paDeviceIndex);
 
-    channelCnt := deviceInfo^.maxInputChannels;
+    channelCnt := paDeviceInfo^.maxInputChannels;
 
     // current device is no input device -> skip
     if (channelCnt <= 0) then
@@ -326,25 +345,25 @@ begin
       channelCnt := 2;
 
     paDevice := TPortaudioInputDevice.Create();
-    AudioInputProcessor.DeviceList[soundCardCnt] := paDevice;
+    AudioInputProcessor.DeviceList[deviceIndex] := paDevice;
 
     // retrieve device-name
-    deviceName := deviceInfo^.name;
+    deviceName := ConvertPaStringToUTF8(paDeviceInfo^.name);
     paDevice.Name := UnifyDeviceName(deviceName, deviceIndex);
-    paDevice.PaDeviceIndex := deviceIndex;
+    paDevice.PaDeviceIndex := paDeviceIndex;
 
-    sampleRate := deviceInfo^.defaultSampleRate;
+    sampleRate := paDeviceInfo^.defaultSampleRate;
 
     // on vista and xp the defaultLowInputLatency may be set to 0 but it works.
     // TODO: correct too low latencies (what is a too low latency, maybe < 10ms?)
-    latency := deviceInfo^.defaultLowInputLatency;
+    latency := paDeviceInfo^.defaultLowInputLatency;
 
     // setup desired input parameters
     // TODO: retry with input-latency set to 20ms (defaultLowInputLatency might
     //       not be set correctly in OSS)
     with inputParams do
     begin
-      device := deviceIndex;
+      device := paDeviceIndex;
       channelCount := channelCnt;
       sampleFormat := paInt16;
       suggestedLatency := latency;
@@ -421,7 +440,7 @@ begin
       for sourceIndex := 1 to sourceCnt do
       begin
         sourceName := Px_GetInputSourceName(mixer, sourceIndex-1);
-        paDevice.Source[sourceIndex].Name := sourceName;
+        paDevice.Source[sourceIndex].Name := ConvertPaStringToUTF8(sourceName);
       end;
 
       Px_CloseMixer(mixer);
@@ -430,13 +449,13 @@ begin
     // close test-stream
     Pa_CloseStream(stream);
 
-    Inc(soundCardCnt);
+    Inc(deviceIndex);
   end;
 
   // adjust size to actual input-device count
-  SetLength(AudioInputProcessor.DeviceList, soundCardCnt);
+  SetLength(AudioInputProcessor.DeviceList, deviceIndex);
 
-  Log.LogStatus('#Input-Devices: ' + inttostr(soundCardCnt), 'Portaudio');
+  Log.LogStatus('#Input-Devices: ' + inttostr(deviceIndex), 'Portaudio');
 
   Result := true;
 end;
-- 
cgit v1.2.3


From 27b3e332076162b37a7a53f059004d23ad69f9d2 Mon Sep 17 00:00:00 2001
From: tobigun <tobigun@b956fd51-792f-4845-bead-9b4dfca2ff2c>
Date: Tue, 27 Apr 2010 19:09:40 +0000
Subject: - device input latency is now configurable via config.ini -
 latency[i] determines the latency for device i in milliseconds or -1 for
 autodetection (default) - this is necessary as mic capturing with portaudio
 (on linux) gets stuck if latency is too low. Either because portaudio's
 latency autodetection does not work or because the mic capture callback takes
 too long before it returns. In both cases the user should set the latency to
 a value of 100 (ms). - better input device test, it should not remove working
 devices anymore.

git-svn-id: svn://svn.code.sf.net/p/ultrastardx/svn/trunk@2313 b956fd51-792f-4845-bead-9b4dfca2ff2c
---
 src/media/UAudioInput_Portaudio.pas | 65 +++++++++++++++++++++++++++----------
 1 file changed, 48 insertions(+), 17 deletions(-)

(limited to 'src/media/UAudioInput_Portaudio.pas')

diff --git a/src/media/UAudioInput_Portaudio.pas b/src/media/UAudioInput_Portaudio.pas
index 26919d42..92e549ff 100644
--- a/src/media/UAudioInput_Portaudio.pas
+++ b/src/media/UAudioInput_Portaudio.pas
@@ -45,6 +45,7 @@ uses
   portmixer,
   {$ENDIF}
   portaudio,
+  ctypes,
   UAudioCore_Portaudio,
   UUnicodeUtils,
   UTextEncoding,
@@ -77,18 +78,19 @@ type
       function Start(): boolean; override;
       function Stop():  boolean; override;
 
+      function DetermineInputLatency(Info: PPaDeviceInfo): TPaTime;
+
       function GetVolume(): single;        override;
       procedure SetVolume(Volume: single); override;
   end;
 
-function MicrophoneCallback(input: pointer; output: pointer; frameCount: longword;
+function MicrophoneCallback(input: pointer; output: pointer; frameCount: culong;
       timeInfo: PPaStreamCallbackTimeInfo; statusFlags: TPaStreamCallbackFlags;
-      inputDevice: pointer): integer; cdecl; forward;
+      inputDevice: pointer): cint; cdecl; forward;
 
-function MicrophoneTestCallback(input: pointer; output: pointer; frameCount: longword;
+function MicrophoneTestCallback(input: pointer; output: pointer; frameCount: culong;
       timeInfo: PPaStreamCallbackTimeInfo; statusFlags: TPaStreamCallbackFlags;
-      inputDevice: pointer): integer; cdecl; forward;
-
+      inputDevice: pointer): cint; cdecl; forward;
 
 {**
  * Converts a string returned by Portaudio into UTF8.
@@ -106,6 +108,33 @@ end;
 
 { TPortaudioInputDevice }
 
+function TPortaudioInputDevice.DetermineInputLatency(Info: PPaDeviceInfo): TPaTime;
+begin
+  if (Ini.InputDeviceConfig[CfgIndex].Latency <> -1) then
+  begin
+    // autodetection off -> set user latency
+    Result := Ini.InputDeviceConfig[CfgIndex].Latency / 1000
+  end
+  else
+  begin
+    // on vista and xp the defaultLowInputLatency may be set to 0 but it works.
+    // TODO: correct too low latencies (what is a too low latency, maybe < 10ms?)
+    // TODO: retry with input-latency set to 20ms (defaultLowInputLatency might
+    //       not be set correctly in OSS)
+
+    // FIXME: according to the portaudio headers defaultHighInputLatency (approx. 40ms) is
+    // for robust non-interactive  applications and defaultLowInputLatency (approx. 15ms)
+    // for interactive performance.
+    // We need defaultLowInputLatency here but this setting is far too buggy. If the callback
+    // does not return quickly the stream will be stuck after returning from the callback
+    // and the callback will not be called anymore and mic-capturing stops.
+    // Audacity (in AudioIO.cpp) uses defaultHighInputLatency if software playthrough is on
+    // and even higher latencies (100ms) without playthrough so this should be ok for now.
+    //Result := Info^.defaultLowInputLatency;
+    Result := Info^.defaultHighInputLatency;
+  end;
+end;
+
 function TPortaudioInputDevice.Open(): boolean;
 var
   Error:       TPaError;
@@ -126,12 +155,12 @@ begin
     device := PaDeviceIndex;
     channelCount := AudioFormat.Channels;
     sampleFormat := paInt16;
-    suggestedLatency := deviceInfo^.defaultLowInputLatency;
+    suggestedLatency := DetermineInputLatency(deviceInfo);
     hostApiSpecificStreamInfo := nil;
   end;
 
-  //Log.LogStatus(deviceInfo^.name, 'Portaudio');
-  //Log.LogStatus(floattostr(deviceInfo^.defaultLowInputLatency), 'Portaudio');
+  Log.LogStatus('Open ' + deviceInfo^.name, 'Portaudio');
+  Log.LogStatus('Latency of ' + deviceInfo^.name + ': ' + floatToStr(inputParams.suggestedLatency), 'Portaudio');
 
   // open input stream
   Error := Pa_OpenStream(RecordStream, @inputParams, nil,
@@ -309,6 +338,8 @@ var
   sourceIndex:  integer;
   sourceName:   UTF8String;
   {$ENDIF}
+const
+  MIN_TEST_LATENCY = 100 / 1000; // min. test latency of 100 ms to avoid removal of working devices
 begin
   Result := false;
 
@@ -354,13 +385,13 @@ begin
 
     sampleRate := paDeviceInfo^.defaultSampleRate;
 
-    // on vista and xp the defaultLowInputLatency may be set to 0 but it works.
-    // TODO: correct too low latencies (what is a too low latency, maybe < 10ms?)
-    latency := paDeviceInfo^.defaultLowInputLatency;
+    // use a stable (high) latency so we do not remove working devices
+    if (paDeviceInfo^.defaultHighInputLatency > MIN_TEST_LATENCY) then
+      latency := paDeviceInfo^.defaultHighInputLatency
+    else
+      latency := MIN_TEST_LATENCY;
 
     // setup desired input parameters
-    // TODO: retry with input-latency set to 20ms (defaultLowInputLatency might
-    //       not be set correctly in OSS)
     with inputParams do
     begin
       device := paDeviceIndex;
@@ -488,9 +519,9 @@ end;
 {*
  * Portaudio input capture callback.
  *}
-function MicrophoneCallback(input: pointer; output: pointer; frameCount: longword;
+function MicrophoneCallback(input: pointer; output: pointer; frameCount: culong;
       timeInfo: PPaStreamCallbackTimeInfo; statusFlags: TPaStreamCallbackFlags;
-      inputDevice: pointer): integer; cdecl;
+      inputDevice: pointer): cint; cdecl;
 begin
   AudioInputProcessor.HandleMicrophoneData(input, frameCount*4, inputDevice);
   result := paContinue;
@@ -499,9 +530,9 @@ end;
 {*
  * Portaudio test capture callback.
  *}
-function MicrophoneTestCallback(input: pointer; output: pointer; frameCount: longword;
+function MicrophoneTestCallback(input: pointer; output: pointer; frameCount: culong;
       timeInfo: PPaStreamCallbackTimeInfo; statusFlags: TPaStreamCallbackFlags;
-      inputDevice: pointer): integer; cdecl;
+      inputDevice: pointer): cint; cdecl;
 begin
   // this callback is called only once
   result := paAbort;
-- 
cgit v1.2.3


From c61600bfdda6608feb6a390d20e2e1200afe93f6 Mon Sep 17 00:00:00 2001
From: tobigun <tobigun@b956fd51-792f-4845-bead-9b4dfca2ff2c>
Date: Fri, 30 Apr 2010 13:49:10 +0000
Subject: portaudio playback (not used by default) segfault fixed

git-svn-id: svn://svn.code.sf.net/p/ultrastardx/svn/trunk@2321 b956fd51-792f-4845-bead-9b4dfca2ff2c
---
 src/media/UAudioInput_Portaudio.pas | 15 ++++-----------
 1 file changed, 4 insertions(+), 11 deletions(-)

(limited to 'src/media/UAudioInput_Portaudio.pas')

diff --git a/src/media/UAudioInput_Portaudio.pas b/src/media/UAudioInput_Portaudio.pas
index 92e549ff..c7364eb4 100644
--- a/src/media/UAudioInput_Portaudio.pas
+++ b/src/media/UAudioInput_Portaudio.pas
@@ -492,27 +492,20 @@ begin
 end;
 
 function TAudioInput_Portaudio.InitializeRecord(): boolean;
-var
-  err: TPaError;
 begin
+  Result := false;
   AudioCore := TAudioCore_Portaudio.GetInstance();
 
   // initialize portaudio
-  err := Pa_Initialize();
-  if (err <> paNoError) then
-  begin
-    Log.LogError(Pa_GetErrorText(err), 'TAudioInput_Portaudio.InitializeRecord');
-    Result := false;
-    Exit;
-  end;
-
+  if (not AudioCore.Initialize()) then
+     Exit;
   Result := EnumDevices();
 end;
 
 function TAudioInput_Portaudio.FinalizeRecord: boolean;
 begin
   CaptureStop;
-  Pa_Terminate();
+  AudioCore.Terminate();
   Result := inherited FinalizeRecord();
 end;
 
-- 
cgit v1.2.3