From 954e0d148d2e6cc0d0e8d57cb8d4d1e8fc197103 Mon Sep 17 00:00:00 2001
From: Alexander Sulfrian <alexander@sulfrian.net>
Date: Mon, 30 Mar 2015 08:12:41 +0200
Subject: Remove plain makefiles. Use cmake.

---
 cmake/FindSDL_gfx.cmake | 88 +++++++++++++++++++++++++++++++++++++++++++++++++
 1 file changed, 88 insertions(+)
 create mode 100644 cmake/FindSDL_gfx.cmake

(limited to 'cmake/FindSDL_gfx.cmake')

diff --git a/cmake/FindSDL_gfx.cmake b/cmake/FindSDL_gfx.cmake
new file mode 100644
index 00000000..314363c2
--- /dev/null
+++ b/cmake/FindSDL_gfx.cmake
@@ -0,0 +1,88 @@
+# - Locate SDL_gfx library
+# This module defines:
+#  SDL_GFX_LIBRARIES, the name of the library to link against
+#  SDL_GFX_INCLUDE_DIRS, where to find the headers
+#  SDL_GFX_FOUND, if false, do not try to link against
+#  SDL_GFX_VERSION_STRING - human-readable string containing the version of SDL_gfx
+#
+# For backward compatiblity the following variables are also set:
+#  SDLGFX_LIBRARY (same value as SDL_GFX_LIBRARIES)
+#  SDLGFX_INCLUDE_DIR (same value as SDL_GFX_INCLUDE_DIRS)
+#  SDLGFX_FOUND (same value as SDL_GFX_FOUND)
+#
+# $SDLDIR is an environment variable that would
+# correspond to the ./configure --prefix=$SDLDIR
+# used in building SDL.
+#
+# Created by Eric Wing. This was influenced by the FindSDL.cmake
+# module, but with modifications to recognize OS X frameworks and
+# additional Unix paths (FreeBSD, etc).
+
+#=============================================================================
+# Copyright 2005-2009 Kitware, Inc.
+# Copyright 2012 Benjamin Eikel
+#
+# Distributed under the OSI-approved BSD License (the "License");
+# see accompanying file Copyright.txt for details.
+#
+# This software is distributed WITHOUT ANY WARRANTY; without even the
+# implied warranty of MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.
+# See the License for more information.
+#=============================================================================
+# (To distribute this file outside of CMake, substitute the full
+#  License text for the above reference.)
+
+if(NOT SDL_GFX_INCLUDE_DIR AND SDLGFX_INCLUDE_DIR)
+  set(SDL_GFX_INCLUDE_DIR ${SDLGFX_INCLUDE_DIR} CACHE PATH "directory cache
+entry initialized from old variable name")
+endif()
+find_path(SDL_GFX_INCLUDE_DIR SDL_gfxPrimitives.h
+  HINTS
+    ENV SDLGFXDIR
+    ENV SDLDIR
+  PATH_SUFFIXES include/SDL include/SDL12 include/SDL11 include
+)
+
+if(NOT SDL_GFX_LIBRARY AND SDLGFX_LIBRARY)
+  set(SDL_GFX_LIBRARY ${SDLGFX_LIBRARY} CACHE FILEPATH "file cache entry
+initialized from old variable name")
+endif()
+find_library(SDL_GFX_LIBRARY
+  NAMES SDL_gfx
+  HINTS
+    ENV SDLGFXDIR
+    ENV SDLDIR
+  PATH_SUFFIXES lib
+)
+
+if(SDL_GFX_INCLUDE_DIR AND EXISTS "${SDL_GFX_INCLUDE_DIR}/SDL_gfxPrimitives.h")
+  file(STRINGS "${SDL_GFX_INCLUDE_DIR}/SDL_gfxPrimitives.h" SDL_GFX_VERSION_MAJOR_LINE REGEX "^#define[ \t]+SDL_GFX_MAJOR_VERSION[ \t]+[0-9]+$")
+  file(STRINGS "${SDL_GFX_INCLUDE_DIR}/SDL_gfxPrimitives.h" SDL_GFX_VERSION_MINOR_LINE REGEX "^#define[ \t]+SDL_GFX_MINOR_VERSION[ \t]+[0-9]+$")
+  file(STRINGS "${SDL_GFX_INCLUDE_DIR}/SDL_gfxPrimitives.h" SDL_GFX_VERSION_PATCH_LINE REGEX "^#define[ \t]+SDL_GFX_PATCHLEVEL[ \t]+[0-9]+$")
+  string(REGEX REPLACE "^#define[ \t]+SDL_GFX_MAJOR_VERSION[ \t]+([0-9]+)$" "\\1" SDL_GFX_VERSION_MAJOR "${SDL_GFX_VERSION_MAJOR_LINE}")
+  string(REGEX REPLACE "^#define[ \t]+SDL_GFX_MINOR_VERSION[ \t]+([0-9]+)$" "\\1" SDL_GFX_VERSION_MINOR "${SDL_GFX_VERSION_MINOR_LINE}")
+  string(REGEX REPLACE "^#define[ \t]+SDL_GFX_PATCHLEVEL[ \t]+([0-9]+)$" "\\1" SDL_GFX_VERSION_PATCH "${SDL_GFX_VERSION_PATCH_LINE}")
+  set(SDL_GFX_VERSION_STRING ${SDL_GFX_VERSION_MAJOR}.${SDL_GFX_VERSION_MINOR}.${SDL_GFX_VERSION_PATCH})
+  unset(SDL_GFX_VERSION_MAJOR_LINE)
+  unset(SDL_GFX_VERSION_MINOR_LINE)
+  unset(SDL_GFX_VERSION_PATCH_LINE)
+  unset(SDL_GFX_VERSION_MAJOR)
+  unset(SDL_GFX_VERSION_MINOR)
+  unset(SDL_GFX_VERSION_PATCH)
+endif()
+
+set(SDL_GFX_LIBRARIES ${SDL_GFX_LIBRARY})
+set(SDL_GFX_INCLUDE_DIRS ${SDL_GFX_INCLUDE_DIR})
+
+include("FindPackageHandleStandardArgs")
+
+FIND_PACKAGE_HANDLE_STANDARD_ARGS(SDL_gfx
+                                  REQUIRED_VARS SDL_GFX_LIBRARIES SDL_GFX_INCLUDE_DIRS
+                                  VERSION_VAR SDL_GFX_VERSION_STRING)
+
+# for backward compatiblity
+set(SDLGFX_LIBRARY ${SDL_GFX_LIBRARIES})
+set(SDLGFX_INCLUDE_DIR ${SDL_GFX_INCLUDE_DIRS})
+set(SDLGFX_FOUND ${SDL_GFX_FOUND})
+
+mark_as_advanced(SDL_GFX_LIBRARY SDL_GFX_INCLUDE_DIR)
-- 
cgit v1.2.3