4 files changed, 379 insertions, 26 deletions
diff --git a/Lua/src/base/UMain.pas b/Lua/src/base/UMain.pas
index 1bd96d41..57ad01a1 100644
--- a/Lua/src/base/UMain.pas
+++ b/Lua/src/base/UMain.pas
@@ -189,6 +189,7 @@ uses
   ULuaLog,
   ULuaTexture,
   ULuaTextGL,
+  ULuaParty,
   UThemes;
 
 
@@ -419,10 +420,13 @@ begin
                   chr(0))
     );  }
 
+    Party := TPartyGame.Create;
+
     LuaCore := TLuaCore.Create;
 
     LuaCore.RegisterModule('Log', ULuaLog_Lib_f);
     LuaCore.RegisterModule('Gl', ULuaGl_Lib_f);
+    LuaCore.RegisterModule('Party', ULuaParty_Lib_f);
 
     LuaCore.BrowseDir(PluginPath);
     LuaCore.DumpPlugins; 
diff --git a/Lua/src/base/UParty.pas b/Lua/src/base/UParty.pas
index b2e31171..2002b861 100644
--- a/Lua/src/base/UParty.pas
+++ b/Lua/src/base/UParty.pas
@@ -105,7 +105,6 @@ type
     bPartyStarted: Boolean;
 
     Modes: array of TParty_ModeInfo;  //< holds info of registred party modes
-    Teams: array of TParty_TeamInfo;  //< holds info of teams playing in current round
 
     TimesPlayed: array of Integer; //< times every mode was played in current party game (for random mode calculation)
 
@@ -117,7 +116,8 @@ type
     function CallLua(Parent: Integer; Func: String):Boolean;
   public
     //Teams: TTeamInfo;
-    Rounds: array of TParty_Round;
+    Rounds: array of TParty_Round;    //< holds info which modes are played in this party game (if started)
+    Teams: array of TParty_TeamInfo;  //< holds info of teams playing in current round (private for easy manipulation of lua functions)
 
     constructor Create;
 
@@ -202,6 +202,9 @@ const
   
   StandardModus = 0; //Modus Id that will be played in non-party mode
 
+var
+  Party: TPartyGame;
+
 implementation
 
 uses
@@ -338,29 +341,6 @@ begin
   end;
 end;
 
-//----------
-// NextRound - Increases CurRound by 1; Returns num of round or -1 if last round is already played
-//----------
-{function TPartyGame.NextRound(wParam: TwParam; lParam: TlParam): integer;
-var
-  I: integer;
-begin
-  if ((CurRound < high(Rounds)) or (CurRound = high(CurRound))) then
-  begin //everythings OK! -> Start the Round, maaaaan
-    Inc(CurRound);
-
-    //Set Players to play this Round
-    for I := 0 to Teams.NumTeams-1 do
-      Teams.Teaminfo[I].CurPlayer := GetRandomPlayer(I);
-
-    // FIXME: return a valid result
-    Result := 0;
-  end
-  else
-    Result := -1;
-end;    }
-
-
 { private: returns true if the players bit is set in the winner int }
 function TPartyGame.IsWinner(Player, Winner: Integer): boolean;
 var
diff --git a/Lua/src/lua/ULuaParty.pas b/Lua/src/lua/ULuaParty.pas
new file mode 100644
index 00000000..f8becdd5
--- /dev/null
+++ b/Lua/src/lua/ULuaParty.pas
@@ -0,0 +1,368 @@
+{* UltraStar Deluxe - Karaoke Game
+ *
+ * UltraStar Deluxe is the legal property of its developers, whose names
+ * are too numerous to list here. Please refer to the COPYRIGHT
+ * file distributed with this source distribution.
+ *
+ * This program is free software; you can redistribute it and/or
+ * modify it under the terms of the GNU General Public License
+ * as published by the Free Software Foundation; either version 2
+ * of the License, or (at your option) any later version.
+ *
+ * This program is distributed in the hope that it will be useful,
+ * but WITHOUT ANY WARRANTY; without even the implied warranty of
+ * MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
+ * GNU General Public License for more details.
+ *
+ * You should have received a copy of the GNU General Public License
+ * along with this program; see the file COPYING. If not, write to
+ * the Free Software Foundation, Inc., 51 Franklin Street, Fifth Floor,
+ * Boston, MA 02110-1301, USA.
+ *
+ * $URL: https://ultrastardx.svn.sourceforge.net/svnroot/ultrastardx/branches/experimental/Lua/src/lua/ULuaGl.pas $
+ * $Id: ULuaGl.pas 1555 2009-01-11 18:19:42Z Hawkear $
+ *}
+
+unit ULuaParty;
+
+interface
+
+{$IFDEF FPC}
+  {$MODE Delphi}
+{$ENDIF}
+
+{$I switches.inc}
+
+uses ULua;
+
+{ lua c functions from Party table. Enables creating of party modes w/ lua scripts }
+
+{ Party.Register - register party mode at party manager
+  arguments: info: table
+                   Name: String;          //< Name used as identifier (language strings, etc.). Has to be set.
+                   CanNonParty: Boolean   //< mode is playable when not in party mode. defaulted to false if not set
+                   CanParty: Boolean      //< mode is playable in party mode. defaulted to false if not set
+                   PlayerCount: Table     //< playable with one, two, three etc. players per team. defaulted to no restrictions if not set. (use table constructor e.g. {1, 2, 3) means playable w/ 1, 2 or three players)
+                   TeamCount: Table       //< playable with one, two, three etc. different teams. defaulted to no restrictions if not set. (use table constructor e.g. {1, 2, 3) means playable w/ 1, 2 or three players)
+
+                   BeforeSongSelect: String   //< name of global that will be called before song select screen is shown (if nil, not callable or returns true, default action will be executed)
+                   AfterSongSelect: String    //< name of global that will be called after song is selected (if nil, not callable or returns true, default action will be executed)
+
+                   BeforeSing: String         //< name of global that will be called before song select screen is shown (if nil, not callable or returns true, default action will be executed)
+                   OnSing: String             //< name of global that will be called before song select screen is shown (if nil, not callable or returns true, default action will be executed)
+                   AfterSing: String          //< name of global that will be called before song select screen is shown (if nil, not callable or returns true, default action will be executed)}
+function ULuaParty_Register(L: Plua_State): Integer; cdecl;
+
+{ Party.GameFinished - returns true if no party game is running or all rounds
+  of current game were played }
+function ULuaParty_GameFinished(L: Plua_State): Integer; cdecl;
+
+{ Party.GetTeams - returns a table with all information and structure as
+  in the TPartyGame.Teams array }
+function ULuaParty_GetTeams(L: Plua_State): Integer; cdecl;
+
+{ Party.SetTeams - changes all fields from TPartyGame.Teams that have been
+  set in the table given as first argument}
+function ULuaParty_SetTeams(L: Plua_State): Integer; cdecl;
+
+const
+  ULuaParty_Lib_f: array [0..4] of lual_reg = (
+    (name:'Register'; func:ULuaParty_Register),
+    (name:'GameFinished'; func:ULuaParty_GameFinished),
+    (name:'GetTeams'; func:ULuaParty_GetTeams),
+    (name:'SetTeams'; func:ULuaParty_SetTeams),
+    (name:nil; func:nil)
+  );
+
+implementation
+uses ULuaCore, UParty, SysUtils;
+
+{ converts a lua table with a structure like:
+    * = 1 , * = 4 , * = 5
+  to an integer with the value:
+    11001
+  does not pop anything }
+function Lua_ToBinInt(L: PLua_State; idx: Integer): Integer;
+  var
+    I: Integer;
+begin
+  // default: no bits set
+  Result := 0;
+
+  lua_checkstack(L, 3);
+
+  if (idx < 0) then
+    dec(idx); // we will push one value before using this
+
+  lua_PushNil(L);
+  while (lua_next(L, idx) <> 0) do
+  begin
+    if (lua_isNumber(L, -1)) then
+    begin //check if we got an integer value from 1 to 32
+      I := lua_toInteger(L, -1);
+      if (I >= 1) and (I <= 32) then
+        Result := Result or 1 shl (I - 1);
+    end;
+
+    // pop value, so key is on top
+    lua_pop(L, 1);
+  end;
+
+
+end;
+
+{ Party.Register - register party mode at party manager
+  arguments: info: table
+                   Name: String;          //< Name used as identifier (language strings, etc.). Has to be set.
+                   CanNonParty: Boolean   //< mode is playable when not in party mode. defaulted to false if not set
+                   CanParty: Boolean      //< mode is playable in party mode. defaulted to false if not set
+                   PlayerCount: Table     //< playable with one, two, three etc. players per team. defaulted to no restrictions if not set. (use table constructor e.g. {1, 2, 3) means playable w/ 1, 2 or three players)
+                   TeamCount: Table       //< playable with one, two, three etc. different teams. defaulted to no restrictions if not set. (use table constructor e.g. {1, 2, 3) means playable w/ 1, 2 or three players)
+
+                   BeforeSongSelect: String   //< name of global that will be called before song select screen is shown (if nil, not callable or returns true, default action will be executed)
+                   AfterSongSelect: String    //< name of global that will be called after song is selected (if nil, not callable or returns true, default action will be executed)
+
+                   BeforeSing: String         //< name of global that will be called before song select screen is shown (if nil, not callable or returns true, default action will be executed)
+                   OnSing: String             //< name of global that will be called before song select screen is shown (if nil, not callable or returns true, default action will be executed)
+                   AfterSing: String          //< name of global that will be called before song select screen is shown (if nil, not callable or returns true, default action will be executed)}
+function ULuaParty_Register(L: Plua_State): Integer; cdecl;
+  var
+    Info: TParty_ModeInfo;
+    Key: String;
+begin
+  // check for table on stack
+  luaL_checkType(L, 1, LUA_TTABLE);
+
+  // get parent id
+  lua_getfield (L, LUA_REGISTRYINDEX, '_USDX_STATE_ID');
+  if (not lua_isNumber(L, -1)) then
+    luaL_error(L, 'unable to get _USDX_STATE_ID in ULuaParty_Register');
+
+
+  // set mode info to default
+  Party.DefaultModeInfo(Info);
+
+
+  // set parent in info rec and pop it from stack
+  Info.Parent := lua_toInteger(L, -1);
+  lua_pop(L, 1);
+
+  // go through table elements
+  lua_pushNil(L);
+  while (lua_Next(L, 1) <> 0) do
+  begin
+    Key := lowercase(lua_ToString(L, -2));
+
+    if (Key = 'name') and lua_isString(L, -1) then
+      Info.Name := lua_toString(L, -1)
+    else if (Key = 'cannonparty') and lua_isBoolean(L, -1) then
+      Info.CanNonParty := lua_toBoolean(L, -1)
+    else if (Key = 'canparty') and lua_isBoolean(L, -1) then
+      Info.CanParty := lua_toBoolean(L, -1)
+    else if (Key = 'playercount') and lua_isTable(L, -1) then
+      Info.playercount := lua_toBinInt(L, -1)
+    else if (Key = 'teamcount') and lua_isTable(L, -1) then
+      Info.teamcount := lua_toBinInt(L, -1)
+    else if (Key = 'beforesongselect') and lua_isString(L, -1) then
+      Info.Functions.BeforeSongSelect := lua_toString(L, -1)
+    else if (Key = 'aftersongselect') and lua_isString(L, -1) then
+      Info.Functions.AfterSongSelect := lua_toString(L, -1)
+    else if (Key = 'beforesing') and lua_isString(L, -1) then
+      Info.Functions.BeforeSing := lua_toString(L, -1)
+    else if (Key = 'onsing') and lua_isString(L, -1) then
+      Info.Functions.OnSing := lua_toString(L, -1)
+    else if (Key = 'aftersing') and lua_isString(L, -1) then
+      Info.Functions.AfterSing := lua_toString(L, -1);
+
+    // pop value from stack so key is on top
+    lua_pop(L, 1);
+  end;
+
+  // clear stack from table
+  lua_pop(L, lua_gettop(L));
+
+  if not Party.RegisterMode(Info) then
+    luaL_error(L, PChar('can''t register party mode at party manager in Party.Register'));
+end;
+
+{ Party.GameFinished - returns true if no party game is running or all rounds
+  of current game were played }
+function ULuaParty_GameFinished(L: Plua_State): Integer; cdecl;
+begin
+  // clear stack
+  lua_pop(L, lua_gettop(L));
+
+  // push result
+  lua_pushBoolean(L, Party.GameFinished);
+
+  //we return one value
+  Result := 1;
+end;
+
+{ Party.GetTeams - returns a table with all information and structure as
+  in the TPartyGame.Teams array }
+function ULuaParty_GetTeams(L: Plua_State): Integer; cdecl;
+  var
+    Team: Integer;
+    Player: Integer;
+begin
+  // clear stack
+  lua_pop(L, lua_gettop(L));
+
+  // ensure we have enough stack slots left
+  lua_checkstack(L, 7);
+
+  // create the table we want to return
+  lua_createtable(L, Length(Party.Teams), 0);
+
+  // add the teams
+  for Team := 0 to High(Party.Teams) do
+  begin
+    // push key for current teams value. lua array beggins at 1
+    lua_pushInteger(L, Team + 1);
+
+    // push table containing team info and players table
+    lua_createtable(L, 0, 5);
+
+    // team name
+    lua_pushString(L, PChar(Party.Teams[Team].Name));
+    lua_setField(L, -2, 'Name');
+
+    // team score
+    lua_pushInteger(L, Party.Teams[Team].Score);
+    lua_setField(L, -2, 'Score');
+
+    // team jokers left
+    lua_pushInteger(L, Party.Teams[Team].JokersLeft);
+    lua_setField(L, -2, 'JokersLeft');
+
+    // team nextPlayer
+    lua_pushInteger(L, Party.Teams[Team].NextPlayer);
+    lua_setField(L, -2, 'NextPlayer');
+
+    // team players table
+    lua_createtable(L, Length(Party.Teams[Team].Players), 0);
+
+    //add players
+    for Player := 0 to High(Party.Teams[Team].Players) do
+    begin
+      // push key for current players value. lua array beggins at 1
+      lua_pushInteger(L, Player + 1);
+
+      // push table containing player info
+      lua_createTable(L, 0, 2);
+
+      // player name
+      lua_PushString(L, PChar(Party.Teams[Team].Players[Player].Name));
+      lua_SetField(L, -2, 'Name');
+
+      // players times played
+      lua_PushInteger(L, Party.Teams[Team].Players[Player].TimesPlayed);
+      lua_SetField(L, -2, 'TimesPlayed');
+
+      // add value - key - pair to teams player table
+      lua_setTable(L, -3);
+    end;
+
+    lua_setField(L, -2, 'Players');
+
+    // add value - key - pair to returned table
+    lua_setTable(L, -3);
+  end;
+
+  // we return 1 value (the first table)
+  Result := 1;
+end;
+
+{ Party.SetTeams - changes all fields from TPartyGame.Teams that have been
+  set in the table given as first argument}
+function ULuaParty_SetTeams(L: Plua_State): Integer; cdecl;
+
+  procedure Do_Player(Team, Player: Integer);
+    var
+      Key: String;
+  begin
+    if (Player >= 0) and (Player <= High(Party.Teams[Team].Players)) then
+    begin
+      // go through table elements
+      lua_pushNil(L);
+      while (lua_Next(L, -2) <> 0) do
+      begin
+        Key := lowercase(lua_ToString(L, -2));
+
+        if (Key = 'name') and lua_isString(L, -1) then
+          Party.Teams[Team].Players[Player].Name := lua_toString(L, -1)
+        else if (Key = 'timesplayed') and lua_isNumber(L, -1) then
+          Party.Teams[Team].Players[Player].TimesPlayed := lua_toInteger(L, -1);
+
+        // pop value from stack so key is on top
+        lua_pop(L, 1);
+      end;
+    end;
+  end;
+
+  procedure Do_Players(Team: Integer);
+  begin
+    // go through table elements
+    lua_pushNil(L);
+    while (lua_Next(L, -2) <> 0) do
+    begin
+      // check if key is a number and value is a table
+      if (lua_isNumber(L, -2)) and (lua_isTable(L, -1)) then
+        Do_Player(Team, lua_toInteger(L, -2));
+
+      // pop value from stack so key is on top
+      lua_pop(L, 1);
+    end;
+  end;
+
+  procedure Do_Team(Team: Integer);
+    var
+      Key: String;
+  begin
+    if (Team >= 0) and (Team <= High(Party.Teams)) then
+    begin
+      // go through table elements
+      lua_pushNil(L);
+      while (lua_Next(L, -2) <> 0) do
+      begin
+        Key := lowercase(lua_ToString(L, -2));
+
+        if (Key = 'name') and lua_isString(L, -1) then
+          Party.Teams[Team].Name := lua_toString(L, -1)
+        else if (Key = 'score') and lua_isNumber(L, -1) then
+          Party.Teams[Team].Score := lua_toInteger(L, -1)
+        else if (Key = 'jokersleft') and lua_isNumber(L, -1) then
+          Party.Teams[Team].JokersLeft := lua_toInteger(L, -1)
+        else if (Key = 'currentplayer') and lua_isNumber(L, -1) then
+          Party.Teams[Team].NextPlayer := lua_toInteger(L, -1)
+        else if (Key = 'players') and lua_isTable(L, -1) then
+          Do_Players(Team);
+
+        // pop value from stack so key is on top
+        lua_pop(L, 1);
+      end;
+    end;
+  end;
+begin
+  // check for table on stack
+  luaL_checkType(L, 1, LUA_TTABLE);
+
+
+  // go through table elements
+  lua_pushNil(L);
+  while (lua_Next(L, 1) <> 0) do
+  begin
+    // check if key is a number and value is a table
+    if (lua_isNumber(L, -2)) and (lua_isTable(L, -1)) then
+      Do_Team(lua_toInteger(L, -2));
+
+    // pop value from stack so key is on top
+    lua_pop(L, 1);
+  end;
+
+  // clear stack from table
+  lua_pop(L, lua_gettop(L));
+end;
+
+end.
+\ No newline at end of file
diff --git a/Lua/src/ultrastardx.dpr b/Lua/src/ultrastardx.dpr
index 10d1e823..cc2f7f0d 100644
--- a/Lua/src/ultrastardx.dpr
+++ b/Lua/src/ultrastardx.dpr
@@ -151,7 +151,8 @@ uses
   ULuaTexture    in 'lua\ULuaTexture.pas',
   UHookableEvent in 'lua\UHookableEvent.pas',
   ULuaCore       in 'lua\ULuaCore.pas',
-  ULuaUsdx       in 'lua\ULuaUsdx.pas', 
+  ULuaUsdx       in 'lua\ULuaUsdx.pas',
+  ULuaParty      in 'lua\ULuaParty.pas',  
 
   //------------------------------
   //Includes - Menu System