From d35747a40c7dea12de95f78a4f283a45ef687597 Mon Sep 17 00:00:00 2001
From: Warren Dukes <warren.dukes@gmail.com>
Date: Mon, 23 Feb 2004 23:41:20 +0000
Subject: import from SF CVS

git-svn-id: https://svn.musicpd.org/mpd/trunk@1 09075e82-0dd4-0310-85a5-a0d7c8717e4f
---
 src/libid3tag/genre.dat.sed | 54 +++++++++++++++++++++++++++++++++++++++++++++
 1 file changed, 54 insertions(+)
 create mode 100644 src/libid3tag/genre.dat.sed

(limited to 'src/libid3tag/genre.dat.sed')

diff --git a/src/libid3tag/genre.dat.sed b/src/libid3tag/genre.dat.sed
new file mode 100644
index 000000000..c65740334
--- /dev/null
+++ b/src/libid3tag/genre.dat.sed
@@ -0,0 +1,54 @@
+#
+# libid3tag - ID3 tag manipulation library
+# Copyright (C) 2000-2003 Underbit Technologies, Inc.
+#
+# This program is free software; you can redistribute it and/or modify
+# it under the terms of the GNU General Public License as published by
+# the Free Software Foundation; either version 2 of the License, or
+# (at your option) any later version.
+#
+# This program is distributed in the hope that it will be useful,
+# but WITHOUT ANY WARRANTY; without even the implied warranty of
+# MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
+# GNU General Public License for more details.
+#
+# You should have received a copy of the GNU General Public License
+# along with this program; if not, write to the Free Software
+# Foundation, Inc., 59 Temple Place, Suite 330, Boston, MA  02111-1307  USA
+#
+# $Id: genre.dat.sed,v 1.1 2003/08/14 03:57:13 shank Exp $
+#
+
+1i\
+/* Automatically generated from genre.dat.in */
+
+# generate an array from a string
+/^[A-Za-z]/{
+H
+y/abcdefghijklmnopqrstuvwxyz/ABCDEFGHIJKLMNOPQRSTUVWXYZ/
+s/[^A-Z0-9]/_/g
+s/.*/static id3_ucs4_t const genre_&[] =/p
+g
+s/.*\n//
+s/./'&', /g
+s/.*/  { &0 };/
+}
+
+# write the final table of arrays
+${
+p
+i\
+\
+static id3_ucs4_t const *const genre_table[] = {
+g
+s/^\(\n\)\(.*\)$/\2\1/
+y/abcdefghijklmnopqrstuvwxyz/ABCDEFGHIJKLMNOPQRSTUVWXYZ/
+s/[^A-Z0-9\n]/_/g
+s/\([^\n]*\)\(\n\)/  genre_\1,\2/g
+s/,\n$//
+a\
+};
+}
+
+# print the pattern space (assumes -n)
+p
-- 
cgit v1.2.3