# Copyright 1999-2010 Gentoo Foundation
# Distributed under the terms of the GNU General Public License v2
# $Header: $

EAPI="2"

inherit eutils subversion autotools

DESCRIPTION="Mifare GUI Tools"
HOMEPAGE="http://code.google.com/p/mtools/"
ESVN_REPO_URI="http://mtools.googlecode.com/svn/trunk/mtools/"
ESVN_PROJECT="mtools"

LICENSE="LGPL-3"
SLOT="0"
KEYWORDS="~x86 ~amd64"

CDEPEND=">=dev-libs/libnfc-1.5.1"
RDEPEND="${CDEPEND}"

src_prepare() {
    epatch "${FILESDIR}/mtools-new-libnfc-version.patch"
    epatch "${FILESDIR}/mtools-new-libfreefare-version.patch"
    epatch "${FILESDIR}/mtools-fix-glade-file-path.patch"

    epatch "${FILESDIR}/mtools-remove-not-working-stuff.patch"
    rm src/gtk/dialogs/KeysChooserDialog.cpp \
        src/gtk/dialogs/InputDialog.cpp \
        src/gtk/dialogs/KeysChooserDialog.h \
        src/gtk/dialogs/InputDialog.h \
        src/gtk/dialogs/KeysStoreDialog.cpp \
        src/gtk/dialogs/KeysStoreDialog.h

    eautoreconf || die "autoreconf failed"
}

src_install() {
    emake DESTDIR="${D}" install || die "Install failed"

    # collision with sys-fs/mtools
    mv "${D}/usr/bin/mtools" "${D}/usr/bin/mifare-tools"

    # install glade file
    insinto "/usr/share/mifare-tools/"
    doins mtools.glade

    dodoc README ChangeLog AUTHORS NEWS || die
}